home *** CD-ROM | disk | FTP | other *** search
/ START Magazine / START VOL 4 NO 1.st / SPLINE.ARC / VIEWSPLN.CTL < prev   
Encoding:
Text File  |  1985-11-20  |  5.0 KB  |  89 lines
  1. ;                          CONTROL SPLINE VIEWER                         
  2. ;               Cyber Control motion control demonstration               
  3. ;                              by Dann Parks                             
  4. ;                 Additional routines by Andrew Reese                    
  5. ;                 Copyright 1989 Antic Publishing, Inc.                  
  6. ;   This program lets you view control splines created by manipulating   
  7. ;                 the objects in the CONTROL.3D2 file.                   
  8. ;------------------------------------------------------------------------
  9. ;                  NOTE: THE WATCH BUFFERS MUST BE ON!                   
  10. ;------------------------------------------------------------------------
  11. ;                  First, set up the general parameters                  
  12. backgnd yes,no:;                      Set the background.                
  13. view s:draft:;                        Set the view mode and rendering.   
  14. ambient 7:;                           Turn up the light.                 
  15. ;------------------------------------------------------------------------
  16. @EXIST
  17. input "[1] Clear splines [2] Show prev splines",oldnew
  18. if oldnew=1 then clrbgnd:;            Clears old splines from backgnd.   
  19. if oldnew<1 then bell:goto EXIST
  20. if oldnew>2 then bell:goto EXIST
  21. ;------------------------------------------------------------------------
  22. @FRAMES
  23. input "How many frames? [Enter 10-100]", num
  24. if num<10 then bell:goto FRAMES:;     Adjust these numbers if you want   
  25. if num>100 then bell:goto FRAMES:;    to change frame limits.            
  26. ;------------------------------------------------------------------------
  27. @INFO
  28. input "[1]Merge CONTROL.3D2 [2]Use existing pts",mergefil
  29. if mergefil=1 then new:merge3d "A:\CONTROL.3D2":;Edit to change pathname.
  30. if mergefil<1 then bell:goto INFO
  31. if mergefil>2 then bell:goto INFO
  32. ;------------------------------------------------------------------------
  33. @FITVIEW
  34. input "Fit view to screen? [1]Yes [2]No",fit
  35. if fit=1 then gosub SETCAM2:;        Send the program to SETCAM2         
  36. ;                                    subroutine to set up camera 2.      
  37. if fit=2 then cam 1 0,90,0:zoom 300:perspec 0:; Or use (and set) camera 1
  38. if mergefil=2 then goto DOIT:;       Skip the marker creator.            
  39. if fit<1 then bell:goto FITVIEW
  40. if fit>2 then bell:goto FITVIEW
  41. ;------------------------------------------------------------------------
  42. ;        Create the marker cube and shrink it to a useable size          
  43. cube mkr,7
  44. group d:clrgrp:select mkr
  45. for shrink=1 to 6
  46. scale 50
  47. next shrink
  48. ;------------------------------------------------------------------------
  49. @DOIT
  50. watch on:;                           Turn on watch buffers.              
  51. group a:clrgrp:select box1:grpcent box1x,box1y,box1z:;  Find the centers 
  52. group a:clrgrp:select box2:grpcent box2x,box2y,box2z:;  of the five      
  53. group a:clrgrp:select box3:grpcent box3x,box3y,box3z:;  spline control   
  54. group a:clrgrp:select box4:grpcent box4x,box4y,box4z:;  point boxes.     
  55. group a:clrgrp:select box5:grpcent box5x,box5y,box5z
  56. ;------------------------------------------------------------------------
  57. defpt 2,box1x,box1y,box1z:;          Use the centers of the five control 
  58. defpt 2,box2x,box2y,box2z:;          point boxes to define five spline   
  59. defpt 2,box3x,box3y,box3z:;          control points.                     
  60. defpt 2,box4x,box4y,box4z
  61. defpt 2,box5x,box5y,box5z
  62. defspline 2,num,b:;                  Define a spline with "num" frames.  
  63. ;------------------------------------------------------------------------
  64. ;                            Main Loop                                   
  65. group b:;                            Select group B.                     
  66. for move=0 to (num-1):;              Set the loop counter to num-1.      
  67. view s:;                             Reset view mode.                    
  68. dec=(move+1)%10:;                    Set 10th frame counter.             
  69. clrgrp:select mkr:;                  Clear group B and select mkr.       
  70. moveto s2x(move),s2y(move),s2z(move):;Put mkr at spline location.        
  71. if move=0 then allgrp:;              Select all objects at the start.    
  72. if dec=0 then bell:view w:;          Bell/wire marker every 10th frame.  
  73. superview:vtobgnd
  74. next move
  75. ;------------------------------------------------------------------------
  76. end:;                                    If finished, end the program.   
  77. ;------------------------------------------------------------------------
  78. @SETCAM2
  79. group a:allgrp:grpcent x,y,z:;       Determine group center.             
  80. bounds minx,miny,minz,maxx,maxy,maxz:;Determine group bounds.            
  81. z1=int(130000/abs(maxy-miny)):;      Derive test value for y-axis        
  82. z2=int(130000/abs(maxx-minx)):;      Derive test value for x-axis        
  83. cam 2 x,y,15000,x,y,z,90:;           Set camera 2 position.              
  84. if z1<z2 then zoom z1:;              Test which value is lower and set   
  85. if z1>z2 then zoom z2:;              zoom to the lower of the two.       
  86. perspec 0
  87. return
  88.  
  89.